新增mqh檔
注意為了要讓MQL5 Wizard在Meta Editor開啟時偵測到追蹤開倉模組，應該把檔案放在 Include\Expert\Trailing\ 中，為了方便管理，我們多建立一層資料夾Include\Expert\Trailing\MyTrailings，並新增SampleTrailing.mqh
完成後得到如下檔案
移除不必要的程式碼並加入算法註解
- 算法邏輯：如果價格按照方向移動了一定距離，則將停損訂單移至無損水準(BE)。
//+------------------------------------------------------------------+
//| SampleTrailing.mqh |
//| Copyright 2024, MetaQuotes Ltd. |
//| <https://www.mql5.com> |
//+------------------------------------------------------------------+
#property copyright "Copyright 2024, MetaQuotes Ltd."
#property link "<https://www.mql5.com>"
//+------------------------------------------------------------------+
//| include files |
//+------------------------------------------------------------------+
#include <Expert\\ExpertTrailing.mqh>
//+------------------------------------------------------------------+
//| Class CSampleTrailing. |
//| Purpose: Class for trailing of open positions |
//| by moving Stop order to a lossless level. |
//| Is derived from the CExpertTrailing class. |
//+------------------------------------------------------------------+
class CSampleTrailing : public CExpertTrailing
{
};
接下來定義需要的參數
- m_profit：移動停損訂單所需的利潤點數距離
- m_stop_level：將停損訂單移動多少點數距離
- 參數設定為protected，由public方法修改，在建立類別時給予初始值
class CSampleTrailing : public CExpertTrailing
{
protected:
int m_profit; // threshold level of profit
int m_stop_level; // lossless level
public:
CSampleTrailing();
//--- method of setting adjustable parameters
void Profit(int value) { m_profit=value; }
void StopLevel(int value) { m_stop_level=value; }
};
//+------------------------------------------------------------------+
//| Constructor CSampleTrailing. |
//| INPUT: no. |
//| OUTPUT: no. |
//| REMARK: no. |
//+------------------------------------------------------------------+
void CSampleTrailing::CSampleTrailing()
{
//--- setting default values
m_profit =20;
m_stop_level=0;
}
ValidationSettings宣告
class CSampleTrailing : public CExpertTrailing
{
protected:
int m_profit; // threshold level of profit
int m_stop_level; // lossless level
public:
CSampleTrailing();
//--- method of setting adjustable parameters
void Profit(int value) { m_profit=value; }
void StopLevel(int value) { m_stop_level=value; }
//--- method of validation of adjustable settings
virtual bool ValidationSettings();
};
驗證參數內容
- 如果移動的點為太小(m_profit-m_stop_levle)則回傳false告知expert錯誤
//+------------------------------------------------------------------+
//| Check of adjustable parameters. |
//| INPUT: no. |
//| OUTPUT: true if the parameters are correct, false if not. |
//| REMARK: no. |
//+------------------------------------------------------------------+
bool CSampleTrailing::ValidationSettings()
{
//--- what if the Init has not been called?
if(m_symbol==NULL) return(false);
//--- check of parameters
if((m_profit-m_stop_level)*m_adjusted_point<=m_symbol.StopsLevel()*m_symbol.Point() && m_profit!=0.0)
{
printf(__FUNCTION__+": threshold level of profit must be greater than the level of setting stop orders");
return(false);
}
//--- ok
return(true);
}
準備工作完成，接下來是演算法的內容，需要改寫CheckTrailingStopLong和CheckTrailingStopShort這兩個方法
class CSampleTrailing : public CExpertTrailing
{
protected:
int m_profit; // threshold level of profit
int m_stop_level; // lossless level
public:
CSampleTrailing();
//--- method of setting adjustable parameters
void Profit(int value) { m_profit=value; }
void StopLevel(int value) { m_stop_level=value; }
//--- method of validation of adjustable settings
virtual bool ValidationSettings();
//--- methods of generation of position modification signals
virtual bool CheckTrailingStopLong(CPositionInfo* position,double& sl,double& tp);
virtual bool CheckTrailingStopShort(CPositionInfo* position,double& sl,double& tp);
};
實作CheckTrailingStopLong 和 CheckTrailingStopShort
- 當滿足以下條件時，會出現修改部位的訊號
- 目前價格跟開倉價超過一定距離則修改部位，到開倉價+m_stop_level的止損位置
- 以下條件不修改
- 如果設定Profit=0不修改
- 如果價格已經設定到BE以上則不修改
//+------------------------------------------------------------------+
//| Check for modification of stop orders of a long position. |
//| INPUT: position - pointer to a position object, |
//| sl - link for a new price of stop loss order, |
//| tp - link for a new price of take profit order. |
//| OUTPUT: true if condition is satisfied, false if not. |
//| REMARK: no. |
//+------------------------------------------------------------------+
bool CSampleTrailing::CheckTrailingStopLong(CPositionInfo* position,double& sl,double& tp)
{
//--- check of pointer
if(position==NULL) return(false);
//--- check of parameters
if(m_profit==0.0) return(false);
//--- already in a lossless zone?
double open=position.PriceOpen();
if(position.StopLoss()>=open) return(false);
//--- check of profit
sl=EMPTY_VALUE;
tp=EMPTY_VALUE;
if(m_symbol.Bid()-open>m_profit*m_adjusted_point)
sl=m_symbol.NormalizePrice(open+m_stop_level*m_adjusted_point);
//---
return(sl!=EMPTY_VALUE);
}
//+------------------------------------------------------------------+
//| Check for modification of stop orders of a short position. |
//| INPUT: position - pointer to a position object, |
//| sl - link for a new price of stop loss order, |
//| tp - link for a new take profit order. |
//| OUTPUT: true if condition is satisfied, false if not. |
//| REMARK: no. |
//+------------------------------------------------------------------+
bool CSampleTrailing::CheckTrailingStopShort(CPositionInfo* position,double& sl,double& tp)
{
//--- check of pointer
if(position==NULL) return(false);
//--- check of parameters
if(m_profit==0.0) return(false);
//--- already in a lossless zone?
double open=position.PriceOpen();
if(position.StopLoss()<=open) return(false);
//--- check of profit
sl=EMPTY_VALUE;
tp=EMPTY_VALUE;
if(open-m_symbol.Ask()>m_profit*m_adjusted_point)
sl=m_symbol.NormalizePrice(open-m_stop_level*m_adjusted_point);
//---
return(sl!=EMPTY_VALUE);
}